#!/usr/bin/fish
rm -r ~/.config/fish/*
stow --no-folding -d ~/.dotfiles -t ~/.config/fish fish

curl -sL https://git.io/fisher | source
fisher install {jorgebucaran/replay,PatrickF1/fzf}.fish
fish_update_completions
ln -s /usr/share/autojump/autojump.fish ~/.config/fish/conf.d
set -U fish_features all
starship init fish --print-full-init > ~/.config/fish/conf.d/starship.fish

alias a 'alias -s'
a acmus 'timeout (math 60 - (date +%M))m mpv --loop https://acmusicext.com/static/$argv/sunny/(date +%-I%P).ogg'
a aliases 'v (env which aliases); command aliases'
a all2jxl 'fd -e{png,jpg,ppm} -x cjxl -e 8 -d 0 {} {.}.jxl \; -x rm'
a awall 'xwinwrap -fdt -fs -- mpv -wid WID ~/Pictures/Wall/Anim/$argv* --loop --no-osc'
a base64d 'echo (echo $argv | base64 -d 2>/dev/null) | tee /dev/stderr 2>| clip;:'
a clip 'xsel -ib'
a cpugov 's cpupower frequency-set -g performance'
a curlflux 'eval curl (cat ~/.config/miniflux)/$argv[1] $argv[2..-1];:'
a dirdl 'wget -r -k -p -np -e robots=off'
a dl 'not test "$argv" && cd ~/Downloads || aria2c -c -{j,s,x}16 --http-accept-gzip'
a dot 'cd ~/.dotfiles'
a drivedl 'dl https://docs.google.com/uc?export=download&id=(echo $argv | cut -d/ -f6)&confirm=t'
a epubpack 'cd $argv && zip -0rX ../(basename $argv).epub mimetype *; cd ..;:'
a ff 'fd -HILi -Edosdevices -E.git'
a fichub 'lynx -dump https://fichub.net/legacy/epub_export?q=$argv | grep epub? | cut -d. -f2- | dl -i-;:'
a fumount 'fusermount -u'
a g git
a gittop 'cd (git root)'
a giveme 's chown $USER'
a gsopti 'fd -e pdf -x gs -sDEVICE=pdfwrite -dNOPAUSE -sOutputFile={}1 {} \; -x mv {}1 {}'
a hardinfo 'inxi -SPARM -GCDN -v1 -xGCRS -Fxz'
a imgsum 'printf "$argv: " && identify -format "%#\n"'
a kittab 'kitty @ launch --type=tab --cwd $PWD'
a l ls
a la 'l -A'
a launcher 'rofi -combi-modi drun,run,window -modi combi -show'
a listen 'pactl list | grep loop && set t un; pactl "$t"load-module module-loopback'
a lock 'budgie-screensaver-command -l'
a magdl 'dl --seed-time=0 magnet:?xt=urn:btih:$argv;:'
a nix '. ~/.nix-profile/etc/profile.d/nix.fish; command nix'
a nsmd 'netsurf (md2html $argv | psub -s .html);:'
a nsp 'netsurf (pandoc $argv -s -t html | psub -s .html);:'
a off shutdown
a pill 's powerpill -Syu'
a png2webp 'fd -e png -x cwebp -z 9 -mt {} -o {.}.webp \; -x rm'
a qb 'qutebrowser --target auto'
a qutainer 'qutebrowser --temp-basedir'
a re 'systemctl reboot -i'
a rmdirs 'ff -t d -x rmdir -p'
a rmlinks 'ff -t l -x rm'
a s 'doas env "PATH=$PATH"'
a sre 'systemctl soft-reboot'
a ssh 'kitty +kitten ssh'
a sus 'systemctl suspend'
a tar bsdtar
a tcsv 'curl https://torrents-csv.com/service/search?q=(echo $argv | tr " " +) | jless;:'
a urldecode 'python3 -c "import sys; from urllib.parse import unquote; print(unquote(sys.stdin.read()))"'
a v vi
a venv 'python3 -m venv venv && source venv/bin/activate.fish && pip3 install -r requirements.txt'
a vi nvim
a wallp 'gsettings set org.gnome.desktop.background picture-uri file://(realpath $argv);:'
a ydl 'yt-dlp'

a 7zstd '7z a -m0=zstd -mx22 -mmt=8 -mfb=273 -md=1536m -ms=on (realpath $argv[1]).7z'
a compress '7z a -m0=flzma2 -mx9 -mmt=8 -mfb=273 -md=1536m -ms=on (realpath $argv[1]).7z'
a dwarf 'mkdwarfs -i . -o $PWD.dwarfs -f --categorize=pcmaudio -C pcmaudio/waveform::flac:level=8'
a dwarfmount 'dwarfs -f $argv (mktemp -d | tee /dev/tty /dev/stderr 2>| clip);:'
a dwarfs 'dwarfs -o offset=auto -o tidy_strategy=swap -o workers=(nproc)'
a dwarfs2null 'dwarfsextract -o /dev/null -f gnutar -i'
a dwarfs2tar 'dwarfsextract -o dwarfs-root.tar -f gnutar -i'
a redwarf 'mkdwarfs -o redwarf.dwarfs --recompress -i'
a squash 'mksquashfs . $PWD.squashfs -comp zstd -b 1M -Xcompression-level 22'
a undwarfs 'mkdir dwarfs-root; dwarfsextract -o dwarfs-root -i'
a xcompress 'fxz -T0 -9 -k'

set junit '(git root)/src/main/java:(git root)/src/test/java:(git root)/../cp/\*'
a jacoco "javacp org.jacoco.cli.internal.Main report (git root)/report/coverage.exec --{class,source}files=(git root)/src/main/java --html report"
a javacp "java -cp $junit"
a junit "javacp -javaagent:(git root)/../cp/jacocoagent.jar=destfile=(git root)/report/coverage.exec org.junit.runner.JUnitCore"
a junitc "javac -cp $junit"

a catbox 'curl https://catbox.moe/user/api.php -F reqtype=fileupload -F fileToUpload=@$argv;:'
a temp 'curl temp.sh -T'
a tldr 'curl -s https://raw.githubusercontent.com/tldr-pages/tldr/main/pages/{common,linux}/$argv.md;:'
a transfer 'curl https://transfer.sh/(basename $argv) -T'

a history_find 'history -p (string sub -s 2 $argv[1]) | head -n1;:'
a history_last 'history -n1;:'

for i in (cut -d ' ' -f1 < ~/.config/qutebrowser/quickmarks)
  a $i "qutebrowser / \":open $i\""
end

for i in deemix encodec git-sim lightnovel-crawler mandown mangadex-downloader\
    mathicsscript pdf2docx portablemc ratarmount scdl soundscrape spleeter
    a $i "pipx run $i"
end
a in2csv 'pipx run --spec csvkit in2csv'
a mathics 'pipx run --spec mathics-django mathicsserver'